mirror of
https://gitlab.freedesktop.org/monado/monado.git
synced 2024-12-26 17:37:34 +00:00
cmake: Switch to a new way of setting options more in line with expectations.
If you explicitly request an option, and it's not available due to dependencies, we now error out instead of silently changing the value.
This commit is contained in:
Ryan Pavlik
parent
38f68dc104
commit
097eeb4f29
|
|
@ -20,6 +20,10 @@ with section("parse"):
|
||||||
"kwargs": {"MANIFEST_TEMPLATE": 1, "OUT_FILE": 1, "RUNTIME_TARGET": 1},
|
"kwargs": {"MANIFEST_TEMPLATE": 1, "OUT_FILE": 1, "RUNTIME_TARGET": 1},
|
||||||
"pargs": {"flags": [], "nargs": "*"},
|
"pargs": {"flags": [], "nargs": "*"},
|
||||||
},
|
},
|
||||||
|
"option_with_deps": {
|
||||||
|
"kwargs": {"DEFAULT": 1, "DEPENDS": "+"},
|
||||||
|
"pargs": {"flags": [], "nargs": "2+"},
|
||||||
|
},
|
||||||
}
|
}
|
||||||
|
|
||||||
with section("format"):
|
with section("format"):
|
||||||
|
|
|
||||||
162
CMakeLists.txt
162
CMakeLists.txt
|
|
@ -42,7 +42,7 @@ set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
|
||||||
###
|
###
|
||||||
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
|
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
|
||||||
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/sanitizers")
|
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/sanitizers")
|
||||||
include(CMakeDependentOption)
|
include(OptionWithDeps)
|
||||||
include(SPIR-V)
|
include(SPIR-V)
|
||||||
include(GNUInstallDirs)
|
include(GNUInstallDirs)
|
||||||
if(NOT GIT_DESC)
|
if(NOT GIT_DESC)
|
||||||
|
|
@ -187,35 +187,91 @@ set(ILLIXR_PATH
|
||||||
# This one is named differently because that's what CTest uses
|
# This one is named differently because that's what CTest uses
|
||||||
option(BUILD_TESTING "Enable building of the test suite?" ON)
|
option(BUILD_TESTING "Enable building of the test suite?" ON)
|
||||||
|
|
||||||
|
if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
|
||||||
|
set(XRT_HAVE_LIBUDEV ON)
|
||||||
|
set(XRT_HAVE_INTERNAL_HID ON)
|
||||||
|
else()
|
||||||
|
option_with_deps(
|
||||||
|
XRT_HAVE_LIBUDEV
|
||||||
|
"Enable libudev (used for device probing on Linux)"
|
||||||
|
ON
|
||||||
|
"UDEV_FOUND"
|
||||||
|
OFF
|
||||||
|
)
|
||||||
|
endif()
|
||||||
|
|
||||||
# cmake-format: off
|
# cmake-format: off
|
||||||
|
|
||||||
option(XRT_FEATURE_COLOR_LOG "Enable logging in color on supported platforms" ON)
|
option(XRT_FEATURE_COLOR_LOG "Enable logging in color on supported platforms" ON)
|
||||||
cmake_dependent_option(XRT_HAVE_PERCETTO "Enable percetto support" ON "PERCETTO_FOUND" OFF)
|
option_with_deps(CMAKE_INTERPROCEDURAL_OPTIMIZATION "Enable inter-procedural (link-time) optimization" DEFAULT OFF DEPENDS HAS_IPO)
|
||||||
cmake_dependent_option(XRT_FEATURE_TRACING "Enable debug tracing on supported platforms" OFF "XRT_HAVE_PERCETTO" OFF)
|
|
||||||
|
|
||||||
cmake_dependent_option(CMAKE_INTERPROCEDURAL_OPTIMIZATION "Enable inter-procedural (link-time) optimization" OFF "HAS_IPO" OFF)
|
option_with_deps(XRT_HAVE_PERCETTO "Enable percetto support" DEPENDS PERCETTO_FOUND)
|
||||||
cmake_dependent_option(XRT_HAVE_WAYLAND "Enable Wayland support" ON "WAYLAND_FOUND AND WAYLAND_SCANNER_FOUND AND WAYLAND_PROTOCOLS_FOUND AND LIBDRM_FOUND" OFF)
|
option_with_deps(XRT_HAVE_WAYLAND "Enable Wayland support" DEPENDS WAYLAND_FOUND WAYLAND_SCANNER_FOUND WAYLAND_PROTOCOLS_FOUND LIBDRM_FOUND)
|
||||||
cmake_dependent_option(XRT_HAVE_WAYLAND_DIRECT "Enable Wayland direct support" ON "XRT_HAVE_WAYLAND AND LIBDRM_FOUND AND WAYLAND_PROTOCOLS_VERSION VERSION_GREATER_EQUAL 1.22" OFF)
|
option_with_deps(XRT_HAVE_WAYLAND_DIRECT "Enable Wayland direct support" DEPENDS XRT_HAVE_WAYLAND LIBDRM_FOUND "WAYLAND_PROTOCOLS_VERSION VERSION_GREATER_EQUAL 1.22")
|
||||||
cmake_dependent_option(XRT_HAVE_XLIB "Enable xlib support" ON "X11_FOUND" OFF)
|
option_with_deps(XRT_HAVE_XLIB "Enable xlib support" DEPENDS X11_FOUND)
|
||||||
cmake_dependent_option(XRT_HAVE_XRANDR "Enable xlib-xrandr support" ON "XRANDR_FOUND" OFF)
|
option_with_deps(XRT_HAVE_XRANDR "Enable xlib-xrandr support" DEPENDS XRANDR_FOUND)
|
||||||
cmake_dependent_option(XRT_HAVE_XCB "Enable xcb support" ON "XCB_FOUND" OFF)
|
option_with_deps(XRT_HAVE_XCB "Enable xcb support" DEPENDS XCB_FOUND)
|
||||||
|
option_with_deps(XRT_HAVE_VULKAN "Enable Vulkan Graphics API support (also needed for compositor)" DEPENDS VULKAN_FOUND)
|
||||||
|
option_with_deps(XRT_HAVE_OPENGL "Enable OpenGL Graphics API support" DEPENDS OPENGL_WITHOUT_GLX_FOUND)
|
||||||
|
option_with_deps(XRT_HAVE_OPENGL_GLX "Enable OpenGL Graphics API support on X11 (GLX)" DEPENDS XRT_HAVE_OPENGL OpenGL_GLX_FOUND)
|
||||||
|
option_with_deps(XRT_HAVE_OPENGLES "Enable OpenGL-ES Graphics API support" DEPENDS OpenGLES_FOUND)
|
||||||
|
option_with_deps(XRT_HAVE_EGL "Enable OpenGL(-ES) on EGL Graphics API support" DEPENDS EGL_FOUND "XRT_HAVE_OPENGL OR XRT_HAVE_OPENGLES")
|
||||||
|
option_with_deps(XRT_HAVE_DBUS "Enable dbus support (for BLE support)" DEPENDS DBUS_FOUND)
|
||||||
|
option_with_deps(XRT_HAVE_LIBBSD "Enable libbsd support" DEPENDS LIBBSD_FOUND)
|
||||||
|
option_with_deps(XRT_FEATURE_TRACING "Enable debug tracing on supported platforms" DEFAULT OFF DEPENDS XRT_HAVE_PERCETTO)
|
||||||
|
option_with_deps(XRT_FEATURE_COMPOSITOR_MAIN "Build main compositor host functionality" DEPENDS XRT_HAVE_VULKAN "XRT_HAVE_WAYLAND OR XRT_HAVE_XCB OR ANDROID OR WIN32")
|
||||||
|
option_with_deps(XRT_FEATURE_OPENXR "Build OpenXR runtime target" DEPENDS XRT_FEATURE_COMPOSITOR_MAIN)
|
||||||
|
option_with_deps(XRT_FEATURE_IPC "Enable the build of the IPC layer" DEPENDS "NOT WIN32")
|
||||||
|
option_with_deps(XRT_FEATURE_SERVICE "Enable separate service module for OpenXR runtime" DEPENDS XRT_FEATURE_IPC XRT_FEATURE_OPENXR)
|
||||||
|
|
||||||
cmake_dependent_option(XRT_HAVE_VULKAN "Enable Vulkan Graphics API support (also needed for compositor)" ON "VULKAN_FOUND" OFF)
|
option_with_deps(XRT_HAVE_SYSTEMD "Enable systemd support (for socket activation of service)" DEPENDS Systemd_FOUND XRT_FEATURE_SERVICE)
|
||||||
cmake_dependent_option(XRT_HAVE_OPENGL "Enable OpenGL Graphics API support" ON "OPENGL_WITHOUT_GLX_FOUND" OFF)
|
option_with_deps(XRT_INSTALL_SYSTEMD_UNIT_FILES "Install user unit files for systemd socket activation on installation" DEPENDS XRT_HAVE_SYSTEMD)
|
||||||
cmake_dependent_option(XRT_HAVE_OPENGL_GLX "Enable OpenGL Graphics API support on X11 (GLX)" ON "XRT_HAVE_OPENGL; OpenGL_GLX_FOUND" OFF)
|
option_with_deps(XRT_INSTALL_ABSOLUTE_SYSTEMD_UNIT_FILES "Use an absolute path to monado-system in installed user unit files for systemd socket activation" DEPENDS XRT_INSTALL_SYSTEMD_UNIT_FILES)
|
||||||
cmake_dependent_option(XRT_HAVE_OPENGLES "Enable OpenGL-ES Graphics API support" ON "OpenGLES_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_HAVE_EGL "Enable OpenGL(-ES) on EGL Graphics API support" ON "EGL_FOUND; XRT_HAVE_OPENGL OR XRT_HAVE_OPENGLES" OFF)
|
|
||||||
|
|
||||||
cmake_dependent_option(XRT_HAVE_DBUS "Enable dbus support (for BLE support)" ON "DBUS_FOUND" OFF)
|
option_with_deps(XRT_FEATURE_STEAMVR_PLUGIN "Build SteamVR plugin" DEPENDS "NOT ANDROID")
|
||||||
cmake_dependent_option(XRT_FEATURE_COMPOSITOR_MAIN "Build main compositor host functionality" ON "XRT_HAVE_VULKAN; XRT_HAVE_WAYLAND OR XRT_HAVE_XCB OR ANDROID OR WIN32" OFF)
|
option_with_deps(XRT_FEATURE_RENDERDOC "Enable RenderDoc API" DEPENDS "RT_LIBRARY OR WIN32")
|
||||||
cmake_dependent_option(XRT_HAVE_LIBBSD "Enable libbsd support" ON "LIBBSD_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_FEATURE_OPENXR "Build OpenXR runtime target" ON "XRT_FEATURE_COMPOSITOR_MAIN" OFF)
|
|
||||||
cmake_dependent_option(XRT_FEATURE_IPC "Enable the build of the IPC layer" ON "NOT WIN32" OFF)
|
option_with_deps(XRT_HAVE_LIBUSB "Enable libusb (used for most drivers)" DEPENDS LIBUSB1_FOUND)
|
||||||
cmake_dependent_option(XRT_FEATURE_SERVICE "Enable separate service module for OpenXR runtime" ON "XRT_FEATURE_IPC AND XRT_FEATURE_OPENXR" OFF)
|
option_with_deps(XRT_HAVE_HIDAPI "Enable libhidapi (used for PSVR)" DEPENDS HIDAPI_FOUND)
|
||||||
cmake_dependent_option(XRT_HAVE_SYSTEMD "Enable systemd support (for socket activation of service)" ON "Systemd_FOUND AND XRT_FEATURE_SERVICE" OFF)
|
option_with_deps(XRT_HAVE_JPEG "Enable jpeg code (used for some video drivers)" DEPENDS JPEG_FOUND)
|
||||||
cmake_dependent_option(XRT_INSTALL_SYSTEMD_UNIT_FILES "Install user unit files for systemd socket activation on installation" ON "XRT_HAVE_SYSTEMD" OFF)
|
option_with_deps(XRT_HAVE_OPENCV "Enable OpenCV backend" DEPENDS OpenCV_FOUND)
|
||||||
cmake_dependent_option(XRT_INSTALL_ABSOLUTE_SYSTEMD_UNIT_FILES "Use an absolute path to monado-system in installed user unit files for systemd socket activation" ON "XRT_INSTALL_SYSTEMD_UNIT_FILES" OFF)
|
option_with_deps(XRT_HAVE_LIBUVC "Enable libuvc video driver" DEPENDS LIBUVC_FOUND XRT_HAVE_LIBUSB)
|
||||||
cmake_dependent_option(XRT_FEATURE_STEAMVR_PLUGIN "Build SteamVR plugin" ON "NOT ANDROID" OFF)
|
option_with_deps(XRT_HAVE_FFMPEG "Enable ffmpeg testing video driver" DEPENDS FFMPEG_FOUND)
|
||||||
|
option_with_deps(XRT_HAVE_SDL2 "Enable use of SDL2" DEPENDS SDL2_FOUND XRT_HAVE_OPENGL)
|
||||||
|
option_with_deps(XRT_HAVE_SYSTEM_CJSON "Enable cJSON from system, instead of bundled source" DEPENDS CJSON_FOUND)
|
||||||
|
option_with_deps(XRT_HAVE_GST "Enable gstreamer" DEPENDS GST_FOUND)
|
||||||
|
option_with_deps(XRT_HAVE_REALSENSE "Enable RealSense support" DEPENDS realsense2_FOUND)
|
||||||
|
option_with_deps(XRT_HAVE_ONNXRUNTIME "Enable ONNX runtime support" DEPENDS ONNXRUNTIME_FOUND)
|
||||||
|
option_with_deps(XRT_HAVE_KIMERA_SLAM "Enable Kimera support" DEPENDS kimera_vio_FOUND)
|
||||||
|
option_with_deps(XRT_HAVE_BASALT_SLAM "Enable Basalt support" DEPENDS basalt_FOUND)
|
||||||
|
option_with_deps(XRT_HAVE_SLAM "Enable SLAM tracking support" DEPENDS SLAM XRT_HAVE_OPENCV)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_PSVR "Enable PSVR HMD driver" DEPENDS XRT_HAVE_HIDAPI)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_REALSENSE "Enable RealSense device driver" DEPENDS XRT_HAVE_REALSENSE)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_VIVE "Enable driver for HTC Vive, Vive Pro, Valve Index, and their controllers" DEPENDS ZLIB_FOUND XRT_HAVE_LINUX)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_OHMD "Enable OpenHMD driver" DEPENDS OPENHMD_FOUND)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_HANDTRACKING "Enable Camera Hand Tracking driver" DEPENDS XRT_HAVE_ONNXRUNTIME XRT_HAVE_OPENCV XRT_HAVE_V4L2)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_DAYDREAM "Enable the Google Daydream View controller driver (BLE, via D-Bus)" DEPENDS XRT_HAVE_DBUS)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_ARDUINO "Enable Arduino input device with BLE via via D-Bus" DEPENDS XRT_HAVE_DBUS)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_ILLIXR "Enable ILLIXR driver" DEPENDS ILLIXR_PATH)
|
||||||
|
option(XRT_BUILD_DRIVER_DUMMY "Enable dummy driver" ON)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_ULV2 "Enable Ultraleap v2 driver" DEPENDS LeapV2_FOUND)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_REMOTE "Enable remote debugging driver" DEPENDS "XRT_HAVE_LINUX OR ANDROID")
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_WMR "Enable Windows Mixed Reality driver" DEPENDS "NOT WIN32")
|
||||||
|
|
||||||
|
option(XRT_BUILD_SAMPLES "Enable compiling sample code implementations that will not be linked into any final targets" ON)
|
||||||
|
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_HDK "Enable HDK driver" DEPENDS XRT_HAVE_INTERNAL_HID)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_PSMV "Enable Playstation Move driver" DEPENDS XRT_HAVE_INTERNAL_HID)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_HYDRA "Enable Hydra driver" DEPENDS XRT_HAVE_INTERNAL_HID)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_NS "Enable North Star driver" DEPENDS XRT_HAVE_INTERNAL_HID)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_VF "Build video frame driver (for video file support, uses gstreamer)" DEPENDS XRT_HAVE_GST)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_DEPTHAI "DepthAI" DEPENDS depthai_FOUND)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_SURVIVE "Enable libsurvive driver" DEPENDS SURVIVE_FOUND)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_ANDROID "Enable Android sensors driver" DEPENDS ANDROID)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_QWERTY "Enable Qwerty driver" DEPENDS XRT_HAVE_SDL2)
|
||||||
|
option_with_deps(XRT_BUILD_DRIVER_EUROC "Enable EuRoC dataset driver for SLAM evaluation" DEPENDS XRT_HAVE_OPENCV)
|
||||||
|
|
||||||
|
# cmake-format: on
|
||||||
|
|
||||||
if(NOT DEFINED XRT_FEATURE_OPENXR_LAYER_DEPTH)
|
if(NOT DEFINED XRT_FEATURE_OPENXR_LAYER_DEPTH)
|
||||||
set(XRT_FEATURE_OPENXR_LAYER_DEPTH ON)
|
set(XRT_FEATURE_OPENXR_LAYER_DEPTH ON)
|
||||||
|
|
@ -233,64 +289,8 @@ if(NOT DEFINED XRT_FEATURE_OPENXR_LAYER_EQUIRECT1)
|
||||||
set(XRT_FEATURE_OPENXR_LAYER_EQUIRECT1 ON)
|
set(XRT_FEATURE_OPENXR_LAYER_EQUIRECT1 ON)
|
||||||
endif()
|
endif()
|
||||||
|
|
||||||
cmake_dependent_option(XRT_FEATURE_RENDERDOC "Enable RenderDoc API" OFF "RT_LIBRARY OR WIN32" OFF)
|
|
||||||
|
|
||||||
# Most users won't touch these.
|
# Most users won't touch these.
|
||||||
mark_as_advanced(XRT_FEATURE_COMPOSITOR_MAIN XRT_FEATURE_OPENXR)
|
mark_as_advanced(XRT_FEATURE_COMPOSITOR_MAIN XRT_FEATURE_OPENXR)
|
||||||
|
|
||||||
|
|
||||||
if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
|
|
||||||
set(XRT_HAVE_LIBUDEV ON)
|
|
||||||
set(XRT_HAVE_INTERNAL_HID ON)
|
|
||||||
else()
|
|
||||||
cmake_dependent_option(XRT_HAVE_LIBUDEV "Enable libudev (used for device probing on Linux)" ON "UDEV_FOUND" OFF)
|
|
||||||
endif()
|
|
||||||
|
|
||||||
cmake_dependent_option(XRT_HAVE_LIBUSB "Enable libusb (used for most drivers)" ON "LIBUSB1_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_HAVE_HIDAPI "Enable libhidapi (used for PSVR)" ON "HIDAPI_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_HAVE_JPEG "Enable jpeg code (used for some video drivers)" ON "JPEG_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_HAVE_OPENCV "Enable OpenCV backend" ON "OpenCV_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_HAVE_LIBUVC "Enable libuvc video driver" ON "LIBUVC_FOUND AND XRT_HAVE_LIBUSB" OFF)
|
|
||||||
cmake_dependent_option(XRT_HAVE_FFMPEG "Enable ffmpeg testing video driver" ON "FFMPEG_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_HAVE_SDL2 "Enable use of SDL2" ON "SDL2_FOUND AND XRT_HAVE_OPENGL" OFF)
|
|
||||||
cmake_dependent_option(XRT_HAVE_SYSTEM_CJSON "Enable cJSON from system, instead of bundled source" ON "CJSON_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_HAVE_GST "Enable gstreamer" ON "GST_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_HAVE_REALSENSE "Enable RealSense support" ON "realsense2_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_HAVE_ONNXRUNTIME "Enable ONNX runtime support" ON "ONNXRUNTIME_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_HAVE_KIMERA_SLAM "Enable Kimera support" ON "kimera_vio_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_HAVE_BASALT_SLAM "Enable Basalt support" ON "basalt_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_HAVE_SLAM "Enable SLAM tracking support" ON "SLAM;XRT_HAVE_OPENCV" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_PSVR "Enable PSVR HMD driver" ON "XRT_HAVE_HIDAPI" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_REALSENSE "Enable RealSense device driver" ON "XRT_HAVE_REALSENSE" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_VIVE "Enable driver for HTC Vive, Vive Pro, Valve Index, and their controllers" ON "ZLIB_FOUND AND XRT_HAVE_LINUX" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_OHMD "Enable OpenHMD driver" ON "OPENHMD_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_HANDTRACKING "Enable Camera Hand Tracking driver" ON "XRT_HAVE_ONNXRUNTIME AND XRT_HAVE_OPENCV AND XRT_HAVE_V4L2" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_DAYDREAM "Enable the Google Daydream View controller driver (BLE, via D-Bus)" ON "XRT_HAVE_DBUS" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_ARDUINO "Enable Arduino input device with BLE via via D-Bus" ON "XRT_HAVE_DBUS" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_ILLIXR "Enable ILLIXR driver" ON "ILLIXR_PATH" OFF)
|
|
||||||
option(XRT_BUILD_DRIVER_DUMMY "Enable dummy driver" ON)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_ULV2 "Enable Ultraleap v2 driver" ON "LeapV2_FOUND" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_REMOTE "Enable remote debugging driver" ON "XRT_HAVE_LINUX OR ANDROID" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_WMR "Enable Windows Mixed Reality driver" ON "NOT WIN32" OFF)
|
|
||||||
|
|
||||||
option(XRT_BUILD_SAMPLES "Enable compiling sample code implementations that will not be linked into any final targets" ON)
|
|
||||||
|
|
||||||
# These all use the Monado internal hid wrapper.
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_HDK "Enable HDK driver" ON "XRT_HAVE_INTERNAL_HID" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_PSMV "Enable Playstation Move driver" ON "XRT_HAVE_INTERNAL_HID" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_HYDRA "Enable Hydra driver" ON "XRT_HAVE_INTERNAL_HID" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_NS "Enable North Star driver" ON "XRT_HAVE_INTERNAL_HID" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_VF "Build video frame driver (for video file support, uses gstreamer)" ON "XRT_HAVE_GST" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_DEPTHAI "DepthAI" ON "depthai_FOUND" OFF)
|
|
||||||
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_SURVIVE "Enable libsurvive driver" ON "SURVIVE_FOUND" OFF)
|
|
||||||
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_ANDROID "Enable Android sensors driver" ON "ANDROID" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_QWERTY "Enable Qwerty driver" ON "XRT_HAVE_SDL2" OFF)
|
|
||||||
cmake_dependent_option(XRT_BUILD_DRIVER_EUROC "Enable EuRoC dataset driver for SLAM evaluation" ON "XRT_HAVE_OPENCV" OFF)
|
|
||||||
|
|
||||||
# cmake-format: on
|
|
||||||
|
|
||||||
# You can set this from a superproject to add a driver
|
# You can set this from a superproject to add a driver
|
||||||
# All drivers must be listed in here to be included in the generated header!
|
# All drivers must be listed in here to be included in the generated header!
|
||||||
list(
|
list(
|
||||||
|
|
|
||||||
166
cmake/OptionWithDeps.cmake
Normal file
166
cmake/OptionWithDeps.cmake
Normal file
|
|
@ -0,0 +1,166 @@
|
||||||
|
# Copyright 2022, Collabora, Ltd.
|
||||||
|
# Copyright 2000-2022 Kitware, Inc., Insight Software Consortium
|
||||||
|
#
|
||||||
|
# SPDX-License-Identifier: BSD-3-Clause
|
||||||
|
#
|
||||||
|
# CMake was initially developed by Kitware with the following sponsorship:
|
||||||
|
# * National Library of Medicine at the National Institutes of Health
|
||||||
|
# as part of the Insight Segmentation and Registration Toolkit (ITK).
|
||||||
|
#
|
||||||
|
# * US National Labs (Los Alamos, Livermore, Sandia) ASC Parallel
|
||||||
|
# Visualization Initiative.
|
||||||
|
#
|
||||||
|
# * National Alliance for Medical Image Computing (NAMIC) is funded by the
|
||||||
|
# National Institutes of Health through the NIH Roadmap for Medical Research,
|
||||||
|
# Grant U54 EB005149.
|
||||||
|
#
|
||||||
|
# * Kitware, Inc.
|
||||||
|
#
|
||||||
|
# (Based on CMakeDependentOption)
|
||||||
|
|
||||||
|
#[=======================================================================[.rst:
|
||||||
|
OptionWithDeps
|
||||||
|
--------------
|
||||||
|
|
||||||
|
Macro to provide an option dependent on other options.
|
||||||
|
|
||||||
|
This macro presents an option to the user only if a set of other
|
||||||
|
conditions are true. If it is already specified by the user but the
|
||||||
|
conditions are not true, it triggers an error.
|
||||||
|
|
||||||
|
This is based on cmake_dependent_options but meets common expectations better:
|
||||||
|
if you explicitly try to enable something that is not available, you get an error
|
||||||
|
instead of just having it silently disabled.
|
||||||
|
|
||||||
|
.. command:: option_with_deps
|
||||||
|
|
||||||
|
.. code-block:: cmake
|
||||||
|
|
||||||
|
option_with_deps(<option> "<help_text>" [DEFAULT <default>] DEPENDS [<depends>...])
|
||||||
|
|
||||||
|
Describes a build option that has dependencies. If the option is requested,
|
||||||
|
but the depends are not satisfied, an error is issued. DEPENDS is a list of
|
||||||
|
conditions to check: all must be true to make the option available.
|
||||||
|
Otherwise, a local variable named ``<option>`` is set to ``OFF``.
|
||||||
|
|
||||||
|
When ``<option>`` is available, the given ``<help_text>`` and initial
|
||||||
|
``<default>`` are used. Otherwise, any value set by the user is preserved for
|
||||||
|
when ``<depends>`` is satisfied in the future.
|
||||||
|
|
||||||
|
Note that the ``<option>`` variable only has a value which satisfies the
|
||||||
|
``<depends>`` condition within the scope of the caller because it is a local
|
||||||
|
variable.
|
||||||
|
|
||||||
|
Elements of ``<depends>`` cannot contain parentheses nor "AND" (each item is
|
||||||
|
implicitly "ANDed" together). Be sure to quote OR and NOT expressions, and avoid
|
||||||
|
complex expressions (such as with escaped quotes, etc) since they may fail,
|
||||||
|
especially before CMake 3.18.
|
||||||
|
|
||||||
|
Example invocation:
|
||||||
|
|
||||||
|
.. code-block:: cmake
|
||||||
|
|
||||||
|
option_with_deps(USE_FOO "Use Foo" DEPENDS "USE_BAR" "NOT USE_ZOT")
|
||||||
|
|
||||||
|
If ``USE_BAR`` is true and ``USE_ZOT`` is false, this provides an option called
|
||||||
|
``USE_FOO`` that defaults to ON. Otherwise, it sets ``USE_FOO`` to OFF and
|
||||||
|
hides the option from the user. If the status of ``USE_BAR`` or ``USE_ZOT``
|
||||||
|
ever changes, any value for the ``USE_FOO`` option is saved so that when the
|
||||||
|
option is re-enabled it retains its old value.
|
||||||
|
|
||||||
|
#]=======================================================================]
|
||||||
|
|
||||||
|
function(option_with_deps option doc)
|
||||||
|
set(options)
|
||||||
|
set(oneValueArgs DEFAULT)
|
||||||
|
set(multiValueArgs DEPENDS)
|
||||||
|
cmake_parse_arguments(_option_deps "${options}" "${oneValueArgs}"
|
||||||
|
"${multiValueArgs}" ${ARGN})
|
||||||
|
|
||||||
|
if(NOT DEFINED _option_deps_DEFAULT)
|
||||||
|
set(_option_deps_DEFAULT ON)
|
||||||
|
endif()
|
||||||
|
|
||||||
|
# Check for invalid/bad depends args
|
||||||
|
foreach(d ${_option_deps_DEPENDS})
|
||||||
|
if("${d}" MATCHES "[(]")
|
||||||
|
message(
|
||||||
|
FATAL_ERROR "option_with_deps does not support parens in deps")
|
||||||
|
endif()
|
||||||
|
if("${d}" MATCHES "\\bAND\\b")
|
||||||
|
message(
|
||||||
|
FATAL_ERROR
|
||||||
|
"option_with_deps treats every deps item as being implicitly 'ANDed' together"
|
||||||
|
)
|
||||||
|
endif()
|
||||||
|
if("${d}" STREQUAL "OR")
|
||||||
|
message(FATAL_ERROR "option_with_deps needs OR expressions quoted")
|
||||||
|
endif()
|
||||||
|
if("${d}" STREQUAL "NOT")
|
||||||
|
message(FATAL_ERROR "option_with_deps needs NOT expressions quoted")
|
||||||
|
endif()
|
||||||
|
endforeach()
|
||||||
|
|
||||||
|
# This is a case we removed from the original CMakeDependentOption module
|
||||||
|
if(NOT (${option}_ISSET MATCHES "^${option}_ISSET$"))
|
||||||
|
message(
|
||||||
|
FATAL_ERROR
|
||||||
|
"Probably too old of CMake version to cope with this module")
|
||||||
|
endif()
|
||||||
|
|
||||||
|
# Check the actual deps, determine if the option is available
|
||||||
|
set(_avail ON)
|
||||||
|
foreach(d ${_option_deps_DEPENDS})
|
||||||
|
if(${CMAKE_VERSION} VERSION_GREATER_EQUAL 3.18)
|
||||||
|
cmake_language(
|
||||||
|
EVAL
|
||||||
|
CODE
|
||||||
|
"
|
||||||
|
if(${d})
|
||||||
|
else()
|
||||||
|
set(_avail OFF)
|
||||||
|
set(_cond ${d})
|
||||||
|
endif()")
|
||||||
|
else()
|
||||||
|
# cmake_language(EVAL CODE was added in 3.18 so evaluate it the "old" way before then.
|
||||||
|
# turn spaces into semicolons so we have a list of arguments, signalling to CMAKE
|
||||||
|
# to interpret the "if()" differently
|
||||||
|
string(REGEX REPLACE " +" ";" CMAKE_DEPENDENT_OPTION_DEP "${d}")
|
||||||
|
if(${CMAKE_DEPENDENT_OPTION_DEP})
|
||||||
|
|
||||||
|
else()
|
||||||
|
set(_avail OFF)
|
||||||
|
set(_cond ${d})
|
||||||
|
endif()
|
||||||
|
endif()
|
||||||
|
endforeach()
|
||||||
|
|
||||||
|
# Error if option was requested but not available
|
||||||
|
if("${${option}}" AND NOT "${_avail}")
|
||||||
|
message(
|
||||||
|
FATAL_ERROR
|
||||||
|
"${option} specified but not available: failed check ${_cond}")
|
||||||
|
endif()
|
||||||
|
|
||||||
|
# Handle remaining cases
|
||||||
|
set(_already_defined OFF)
|
||||||
|
if(DEFINED ${option})
|
||||||
|
set(_already_defined ON)
|
||||||
|
endif()
|
||||||
|
if(${_avail})
|
||||||
|
# Set a cache variable: the value here will not override an already-set value.
|
||||||
|
option(${option} "${doc}" "${_option_deps_DEFAULT}")
|
||||||
|
|
||||||
|
if(NOT _already_defined)
|
||||||
|
# Needed to force this for some reason
|
||||||
|
set(${option}
|
||||||
|
"${${option}}"
|
||||||
|
CACHE BOOL "${doc}" FORCE)
|
||||||
|
endif()
|
||||||
|
else()
|
||||||
|
# Don't set a cache variable for something that's not available
|
||||||
|
set(${option}
|
||||||
|
OFF
|
||||||
|
PARENT_SCOPE)
|
||||||
|
endif()
|
||||||
|
endfunction()
|
||||||
|
|
@ -1,16 +1,21 @@
|
||||||
# Copyright 2018-2020, Collabora, Ltd.
|
# Copyright 2018-2022, Collabora, Ltd.
|
||||||
# SPDX-License-Identifier: BSL-1.0
|
# SPDX-License-Identifier: BSL-1.0
|
||||||
|
|
||||||
# check if Doxygen is installed
|
# check if Doxygen is installed
|
||||||
find_package(Doxygen)
|
find_package(Doxygen)
|
||||||
|
|
||||||
# cmake-format: off
|
option_with_deps(BUILD_DOC "Build documentation" DEPENDS DOXYGEN_FOUND)
|
||||||
|
option_with_deps(
|
||||||
cmake_dependent_option(BUILD_DOC "Build documentation" ON "DOXYGEN_FOUND" OFF)
|
BUILD_DOC_WARN_UNDOCUMENTED "Warn on undocumented entities when building documentation"
|
||||||
cmake_dependent_option(BUILD_DOC_WARN_UNDOCUMENTED "Warn on undocumented entities when building documentation" OFF "DOXYGEN_FOUND" OFF)
|
DEFAULT OFF
|
||||||
cmake_dependent_option(BUILD_DOC_EXTRACT_ALL "Extract all entities for documentation, not just documented ones (conflicts with BUILD_DOC_WARN_UNDOCUMENTED)" ON "DOXYGEN_FOUND AND NOT BUILD_DOC_WARN_UNDOCUMENTED" OFF)
|
DEPENDS DOXYGEN_FOUND
|
||||||
|
)
|
||||||
# cmake-format: on
|
option_with_deps(
|
||||||
|
BUILD_DOC_EXTRACT_ALL
|
||||||
|
"Extract all entities for documentation, not just documented ones (conflicts with BUILD_DOC_WARN_UNDOCUMENTED)"
|
||||||
|
DEFAULT OFF
|
||||||
|
DEPENDS DOXYGEN_FOUND "NOT BUILD_DOC_WARN_UNDOCUMENTED"
|
||||||
|
)
|
||||||
|
|
||||||
if(BUILD_DOC)
|
if(BUILD_DOC)
|
||||||
if(BUILD_DOC_WARN_UNDOCUMENTED)
|
if(BUILD_DOC_WARN_UNDOCUMENTED)
|
||||||
|
|
|
||||||
|
|
@ -88,8 +88,11 @@ target_link_libraries(
|
||||||
PUBLIC aux_os
|
PUBLIC aux_os
|
||||||
)
|
)
|
||||||
|
|
||||||
if(DEFINED XRT_FEATURE_RENDERDOC)
|
if(XRT_FEATURE_RENDERDOC)
|
||||||
target_link_libraries(st_oxr PRIVATE xrt-external-renderdoc)
|
target_link_libraries(st_oxr PUBLIC xrt-external-renderdoc)
|
||||||
|
if(XRT_HAVE_LINUX)
|
||||||
|
target_link_libraries(st_oxr PRIVATE ${CMAKE_DL_LIBS})
|
||||||
|
endif()
|
||||||
endif()
|
endif()
|
||||||
|
|
||||||
target_include_directories(
|
target_include_directories(
|
||||||
|
|
|
||||||
Loading…
Reference in a new issue